WebGadget в режиме редактора
Интересный способ работы
WebGadget в режиме редактора.
Создавать странички с нуля не самый лучший вариант, а редактировать текст уже готовых - очень удобно.
Для правильного редактирования, сначала через Ваш любимый браузер
(Opera, Internet Explorer или Firefox )загружаем понравившуюся интернет странички
например на рабочий стол: правой кнопкой мыши - сохранить исходный код
страницы с изображениями.
Появляется папка с дополнительными файлами (скрипты,
стили, картинки ) и сам
html файл. Если редактировать в интернете, то
стиль страницы будет потерян.
Лучше редактировать файл на локальном компьютере, а не в сети.
После редактирования сохраняем
html файл через меню или выделяем код правой кнопкой мыши.
Путь к изображениям и файлам,будет указан абсолютный (необходимо дальнейшее редактирование).
Код редактора для версии PureBasic 4.40 :
<![CDATA[
;--------------------WebGadget в режиме визуального редактора-----------------------
;
; Поделился идеей kvitaliy
;
; http://purebasic.info/phpBB2/viewtopic.php?t=1035&postdays=0&postorder=asc&start=15&sid=9f7a907c5ebfbb1c957bf1d9e575379e
;
;-----------------------------------------------------------------------------------
#idm_2d_position = 2394 ; для перетягивания объектов
#IDM_IMAGE = 2168 ; вставить изображения
#IDM_HYPERLINK = 2124 ; гиперссылка
#IDM_BROWSEMODE = 2126 ; режим браузера
#IDM_EDITMODE = 2127 ; режим редактирования
#IDM_BOLD = 52 ; жирный шрифт
#IDM_JUSTIFYCENTER = 57 ; текст по центру
#IDM_INDENT = 2186 ; отступ от левого края
#IDM_ITALIC = 56 ; шрифт Italic
#IDM_ORDERLIST = 2184 ; нумерованный список
#IDM_UNORDERLIST = 2185 ; не нумерованный список
#IDM_TRISTATEUNDERLINE= 97 ; текст подчёркнут
#IDM_HORIZONTALLINE = 2150 ; оризонтальная линия
#IDM_INSFIELDSET = 2119 ; предназначен для группирования элементов формы
#IDM_MARQUEE = 2182 ; создать бегущею строку
#IDM_SAVEAS = 71 ; сохранить
#IDM_REFRESH = 2300 ; обновить
#IDM_REDO = 29 ; на шаг вперёд
#IDM_UNDO = 43 ; на шаг назад
#IDM_FONTSIZE = 90 ; выбор шрифта и размер
Global Browser.IWebBrowser2,EDITMODE=0
Global CmdTarget.IOleCommandTarget
Enumeration 0
#OLECMDEXECOPT_DODEFAULT
#olecmdexecopt_promptuser
#olecmdexecopt_dontpromptuser
#olecmdexecopt_showhelp
EndEnumeration
;- враппер команд
Procedure ExecWB(WhatAction.l)
CmdTarget\Exec(?CGID_MSHTML, WhatAction, #OLECMDEXECOPT_DODEFAULT, 0, 0)
EndProcedure
UsePNGImageDecoder()
UseJPEGImageDecoder()
Enumeration
#Window_0
#Web
#Strin_1
#But_1
#Img_1
EndEnumeration
Enumeration
#pos
EndEnumeration
;{--------------------------------------------------------------------------------------------------------------------------------------------
Procedure Brayz()
Browser.IWebBrowser2 = GetWindowLong_(GadgetID(#Web), #GWL_USERDATA)
;Ждем загрузку страницы..
Repeat
While WindowEvent(): Wend
Delay(1)
Browser\get_Busy(@IsBusy.l)
Until IsBusy = 0
; Доступ к интерфейсу документа
If Browser\get_Document(@DocumentDispatch.IDispatch) = #S_OK
If DocumentDispatch\QueryInterface(?IID_IHTMLDocument2, @Document.IHTMLDocument2) = #S_OK
Document\put_designMode("Of") ; Переходим в режим редактирования
If DocumentDispatch\QueryInterface(?IID_IOleCommandTarget, @CmdTarget.IOleCommandTarget) = #S_OK
CmdTarget\Exec(?CGID_MSHTML, #idm_2d_position, #olecmdexecopt_dontpromptuser, @var, NULL) ;Поддержка перетаскивания обьектов
EndIf
Document\Release()
EndIf
DocumentDispatch\Release()
EndIf
EndProcedure
;}---------------------------------------------------------------------------------------------------------------------------------------------
CatchImage(#pos, ?Im0, ?Im0End -?Im0 )
CatchImage(1, ?Im1, ?Im1End -?Im1 )
CatchImage(2, ?Im2, ?Im2End -?Im2 )
CatchImage(3, ?Im3, ?Im3End -?Im3 )
CatchImage(14, ?Im14, ?Im14End -?Im14 )
CatchImage(15, ?Im15, ?Im15End -?Im15 )
CatchImage(16, ?Im16, ?Im16End -?Im16 )
CatchImage(17, ?Im17, ?Im17End -?Im17 )
CatchImage(18, ?Im18, ?Im18End -?Im18 )
CatchImage(19, ?Im19, ?Im19End -?Im19 )
CatchImage(20, ?Im20, ?Im20End -?Im20 )
CatchImage(21, ?Im21, ?Im21End -?Im21 )
CatchImage(22, ?Im22, ?Im22End -?Im22 )
CatchImage(23, ?Im23, ?Im23End -?Im23 )
CatchImage(24, ?Im24, ?Im24End -?Im24 )
CatchImage(25, ?Im25, ?Im25End -?Im25 )
CatchImage(26, ?Im26, ?Im26End -?Im26 )
CatchImage(27, ?Im27, ?Im27End -?Im27 )
CatchImage(28, ?Im28, ?Im28End -?Im28 )
CatchImage(29, ?Im29, ?Im29End -?Im29 )
CatchImage(30, ?Im30, ?Im30End -?Im30 )
CatchImage(31, ?Im31, ?Im31End -?Im31 )
CatchImage(32, ?Im32, ?Im32End -?Im32 )
CatchImage(33, ?Im33, ?Im33End -?Im33 )
CatchImage(34, ?Im34, ?Im34End -?Im34 )
CatchImage(35, ?Im35, ?Im35End -?Im35 )
;{------------------Окно--------------------------------
OpenWindow(#Window_0, 0, 0, 800, 600, "HTML Visual Editor",#PB_Window_MinimizeGadget |#PB_Window_MaximizeGadget|#PB_Window_ScreenCentered|#PB_Window_SizeGadget)
StringGadget(#Strin_1, 210, 28, 450, 20, "http://purebasic.info/") ; поле для адресса
ButtonGadget(#But_1, 680, 27, 70, 22, "Загрузить") ; загрузить адрес
ImageGadget(#Img_1, 5, 28, 180, 25, ImageID(32)) ; логотип
;---------Панель инструментов----------------------------------------------
If CreateToolBar(0,WindowID(#Window_0))
ToolBarImageButton(1,ImageID(1)) ; новый
ToolBarImageButton(2,ImageID(2)) ; открыть
ToolBarImageButton(3,ImageID(3)) ; сохранить
ToolBarImageButton(#pos,ImageID(0))
ToolBarImageButton(14,ImageID(14)) ; на шаг назад
ToolBarImageButton(15,ImageID(15)) ; на шаг вперёд
ToolBarImageButton(#pos,ImageID(0))
ToolBarSeparator()
ToolBarImageButton(16,ImageID(16)) ; режим редактирования или просмотра
ToolBarSeparator()
ToolBarImageButton(#pos,ImageID(0))
ToolBarImageButton(17,ImageID(17)) ; изображение
ToolBarImageButton(18,ImageID(18)) ; ссылка
ToolBarImageButton(19,ImageID(19)) ; текст жирный
ToolBarImageButton(20,ImageID(20)) ; текст Italic
ToolBarImageButton(21,ImageID(21)) ; текст подчёркнутый
ToolBarImageButton(22,ImageID(22)) ; текст по середине
ToolBarImageButton(23,ImageID(23)) ; левый отступ
ToolBarImageButton(24,ImageID(24)) ; не нумерованный список
ToolBarImageButton(25,ImageID(25)) ; нумерованный список
ToolBarImageButton(26,ImageID(26)) ; бегущая строка
ToolBarImageButton(27,ImageID(27)) ; группирования элементов формы
ToolBarImageButton(28,ImageID(28)) ; горизонтальная линия
ToolBarImageButton(32,ImageID(33)) ; выбор шрифта и размер
ToolBarImageButton(33,ImageID(34)) ; с новой строки
ToolBarImageButton(#pos,ImageID(0))
ToolBarImageButton(34,ImageID(35)) ; удалить
ToolBarImageButton(#pos,ImageID(0))
ToolBarSeparator()
ToolBarImageButton(#pos,ImageID(0))
ToolBarImageButton(29,ImageID(29)) ; браузер <<<
ToolBarImageButton(30,ImageID(30)) ; обновить браузер
ToolBarImageButton(31,ImageID(31)) ; браузер <<<
EndIf
;---------------------------------------------------------------------------------
;GadgetToolTip(#Strin_1,"Поле для интернет адресса") ; всплывающая подсказка
;GadgetToolTip(#But_1, "Загрузить адрес")
ToolBarToolTip(0, 1, "Новый")
ToolBarToolTip(0, 2, "Открыть файл")
ToolBarToolTip(0, 3, "Сохранить")
ToolBarToolTip(0, 14, "На шаг назад")
ToolBarToolTip(0, 15, "На шаг вперёд")
ToolBarToolTip(0, 16, "Режим просмотра или редактирования")
ToolBarToolTip(0, 17, "Вставить изображение")
ToolBarToolTip(0, 18, "Вставить гиперссылку")
ToolBarToolTip(0, 19, "Текст жирный")
ToolBarToolTip(0, 20, "Текст Italic")
ToolBarToolTip(0, 21, "Текст подчёркнутый")
ToolBarToolTip(0, 22, "Текст по центру")
ToolBarToolTip(0, 23, "Левый отступ")
ToolBarToolTip(0, 24, "Не нумерованный список")
ToolBarToolTip(0, 25, "Нумерованный список")
ToolBarToolTip(0, 26, "Бегущая строка")
ToolBarToolTip(0, 27, "Группирования элементов формы")
ToolBarToolTip(0, 28, "Горизонтальная линия")
ToolBarToolTip(0, 29, "Браузер <<<")
ToolBarToolTip(0, 30, "Обновить браузер")
ToolBarToolTip(0, 31, "Браузер >>>")
ToolBarToolTip(0, 32, "Шрифт и размер")
ToolBarToolTip(0, 33, "С новой строки")
ToolBarToolTip(0, 34, "Удалить выделенный обьект")
;------------------Меню-----------------------------------------------------------
If CreateMenu(1, WindowID(#Window_0))
MenuTitle("Файл") ; Заголовок меню.
MenuItem(1,"Новый" +Chr(9)+"Ctrl+N")
MenuItem(2,"Открыть" +Chr(9)+"Ctrl+O")
MenuItem(3,"Сохранить" +Chr(9)+"Ctrl+S")
MenuItem(4,"Сохранить как")
MenuBar()
MenuItem(6,"Выход")
MenuTitle("Правка")
MenuItem(7, "Отменить" +Chr(9)+"Ctrl+Z")
MenuItem(8,"Повторить" +Chr(9)+"Ctrl+Y")
MenuBar()
MenuItem(9, "Вырезать" +Chr(9)+"Ctrl+X")
MenuItem(10, "Копировать"+Chr(9)+"Ctrl+C")
MenuItem(11, "Вставить" +Chr(9)+"Ctrl+V")
MenuItem(12, "Удалить")
MenuBar()
MenuItem(13,"Выделить всё" +Chr(9)+"Ctrl+A")
MenuBar()
MenuTitle("Инструменты")
MenuItem(14, "На шаг назад")
MenuItem(15, "На шаг вперёд")
MenuBar()
MenuItem(16, "Редактирование/просмотр")
MenuBar()
MenuItem(17, "Вставить изображение")
MenuItem(18, "Вставить гиперссылку")
MenuItem(19, "Текст жирный")
MenuItem(20, "Текст Italic")
MenuItem(21, "Текст подчёркнутый")
MenuItem(22, "Текст по центру")
MenuItem(23, "Левый отступ")
MenuItem(24, "Не нумерованный список")
MenuItem(25, "Нумерованный список")
MenuItem(26, "Бегущая строка")
MenuItem(27, "Группирования элементов формы")
MenuItem(28, "Горизонтальная линия")
MenuBar()
MenuItem(29, "Браузер <<<")
MenuItem(30, "Обновить браузер")
MenuItem(31, "Браузер >>>")
MenuTitle("Помощь")
MenuItem(32, "Справка")
MenuBar()
MenuItem(33, "О программе")
EndIf
;-----------------------------------------------------------------------------------
ProgPath.s=GetPathPart(ProgramFilename())
WebGadget(#Web, 5, 55, 790, 520, "") ; Web браузер
Brayz()
;}------------------------------------------------------
;{----------------- Главный цикл -------------------------
Repeat
Event = WaitWindowEvent()
Window = EventWindow()
Gadget = EventGadget()
Select Event
Case #PB_Event_Gadget
Select EventGadget()
Case #But_1
SetGadgetText(#Web, GetGadgetText(#Strin_1)) ; загрузить текст адресса из #Strin_1 в #Web
EndSelect
EndSelect
Menu=EventMenu() ; Узнаём идентификатор пункта меню, в котором произошло событие
If Event= #PB_Event_Menu ; Обрабатываем события от меню.
Select Menu
Case 1
SetGadgetText(#Web, "file://localhost/"+ProgPath+"Template/Template.htm")
Case 2
OpenFile.s=OpenFileRequester("Открыть файл", "", "Все файлы|*.*", 0) ; полный путь к файлу
SetGadgetText(#Web, OpenFile.s)
SetGadgetText(#Strin_1, OpenFile.s) ; загружаем в #Web абсолютный адресс
Case 3
ExecWB(#IDM_SAVEAS) ; Сохранить
Case 14
ExecWB(#IDM_UNDO) ; на шаг назад
Case 15
ExecWB(#IDM_REDO) ; на шаг вперёд
Case 16
If EDITMODE
ExecWB(#IDM_BROWSEMODE) ; Переключаем в режим просмотра странички
EDITMODE=0
Else
ExecWB(#IDM_EDITMODE) ; Переключаем в режим редактирования
EDITMODE=1
EndIf
Case 17
ExecWB(#IDM_HYPERLINK) ; вставить гиперссылку
Case 18
ExecWB(#IDM_IMAGE) ; вставить рисунок
Case 19
ExecWB(#IDM_BOLD) ; жирный
Case 20
ExecWB(#IDM_ITALIC) ; шрифт Italic
Case 21
ExecWB(#IDM_TRISTATEUNDERLINE) ; текст подчёркнут
Case 22
ExecWB(#IDM_JUSTIFYCENTER) ; текст по центру
Case 23
ExecWB(#IDM_INDENT) ; отступ от левого края
Case 24
ExecWB(#IDM_UNORDERLIST) ; не нумерованный список
Case 25
ExecWB(#IDM_ORDERLIST) ; нумерованный список
Case 26
ExecWB(#IDM_MARQUEE) ; бегущая строка
Case 27
ExecWB(#IDM_INSFIELDSET) ; группирования элементов формы
Case 28
ExecWB(#IDM_HORIZONTALLINE) ; оризонтальная линия
Case 29
SetGadgetState(#Web, #PB_Web_Back) ; вернуться на шаг назад в браузере
Case 30
ExecWB(#IDM_REFRESH) ; обновить браузер
Case 31
SetGadgetState(#Web, #PB_Web_Forward); вернуться на шаг вперёд в браузере
Case 32
ExecWB(#IDM_FONTSIZE) ; выбор шрифта и размер
Case 33
ExecWB(2152) ; с новой строки
Case 34
ExecWB(92) ; удалить выделенный обьект
EndSelect
EndIf
If Event=#PB_Event_SizeWindow ; Изменяем размер редактора при изменении размеров окна
ResizeGadget(#Web,#PB_Ignore,#PB_Ignore, WindowWidth(#Window_0)-20, WindowHeight(#Window_0)-60)
EndIf
If Event = #PB_Event_CloseWindow
Break ;CloseWindow(Window) ; если много окон
EndIf
ForEver ;Until Event=#PB_Event_CloseWindow And Window=#Window_0 ; если много окон
;}-------------------------------------------------------
DataSection
Im0:
IncludeBinary "pos.png"
Im0End:
Im1:
IncludeBinary "новый_PB.png"
Im1End:
Im2:
IncludeBinary "сохр_PB_2.png"
Im2End:
Im3:
IncludeBinary "сохр_PB.png"
Im3End:
Im14:
IncludeBinary "назад.png"
Im14End:
Im15:
IncludeBinary "вперёд.png"
Im15End:
Im16:
IncludeBinary "редактирование.png"
Im16End:
Im17:
IncludeBinary "Linc_1.png"
Im17End:
Im18:
IncludeBinary "img_1.png"
Im18End:
Im19:
IncludeBinary "b.png"
Im19End:
Im20:
IncludeBinary "italic.png"
Im20End:
Im21:
IncludeBinary "подчеркнут.png"
Im21End:
Im22:
IncludeBinary "центр.png"
Im22End:
Im23:
IncludeBinary "л_отступ.png"
Im23End:
Im24:
IncludeBinary "список.png"
Im24End:
Im25:
IncludeBinary "список_2.png"
Im25End:
Im26:
IncludeBinary "бегущая_строка_2.png"
Im26End:
Im27:
IncludeBinary "контейнер.png"
Im27End:
Im28:
IncludeBinary "линия.png"
Im28End:
Im29:
IncludeBinary "назад_1.png"
Im29End:
Im30:
IncludeBinary "arrow_refresh.png"
Im30End:
Im31:
IncludeBinary "вперёд_1.png"
Im31End:
Im32:
IncludeBinary "лого_1.png"
Im32End:
Im33:
IncludeBinary "style.png"
Im33End:
Im34:
IncludeBinary "br.png"
Im34End:
Im35:
IncludeBinary "delete.png"
Im35End:
IID_IHTMLDocument2: ; {332c4425-26cb-11d0-b483-00c04fd90119}
Data.l $332C4425
Data.w $26CB, $11D0
Data.b $B4, $83, $00, $C0, $4F, $D9, $01, $19
IID_IOleCommandTarget: ; {b722bccb-4e68-101b-a2bc-00aa00404770}
Data.l $B722BCCB
Data.w $4E68, $101B
Data.b $A2, $BC, $00, $AA, $00, $40, $47, $70
CGID_MSHTML: ; { 0xDE4BA900, 0x59CA, 0x11CF, { 0x95, 0x92, 0x44, 0x45, 0x53, 0x54, 0x00, 0x00 } }
Data.l $DE4BA900
Data.w $59CA, $11CF
Data.b $95, $92, $44, $45, $53, $54, $00, $00
EndDataSection
; 2D-Position IDM_2D_POSITION (0x095A) 2394 для перетягивания объектов
; AbsolutePosition IDM_ABSOLUTE_POSITION (0x095D) 2397
; AutoDetect IDM_AUTODETECT (0x0919) 2329
; BackColor IDM_BACKCOLOR (0x0033) 51
; BackgroundImageCache IDM_BACKGROUNDIMAGECACHE (0x097E) 2430
; BlockDirLTR IDM_BLOCKDIRLTR (0x0930) 2352
; BlockDirRTL IDM_BLOCKDIRRTL (0x0931)
; Bold IDM_BOLD (0x0034) 52 жирный текст
; BrowseMode IDM_BROWSEMODE (0x084E) 2126 -------
; ClearAuthenticationCache IDM_CLEARAUTHENTICATIONCACHE (0x3A9B) 15003
; Copy IDM_COPY (0x000F) 15
; CreateBookmark IDM_BOOKMARK (0x084B) 2123
; CreateLink IDM_HYPERLINK (0x084C) 2124 гиперссылка
; Cut IDM_CUT (0x0010) 16 вырезать объкт
; Delete IDM_DELETE (0x0011) 17 удалить объкте
; DirLTR IDM_DIRLTR (0x092E) 2350
; DirRTL IDM_DIRRTL (0x092F)
; EditMode IDM_EDITMODE (0x084F) 2127 --------
; FontName IDM_FONTNAME (0x0012) 18
; FontSize IDM_FONTSIZE (0x0013) 19
; ForeColor IDM_FORECOLOR (0x0037) 55
; FormatBlock IDM_BLOCKFMT (0x08BA) 2234
; GetBlockFormats IDM_GETBLOCKFMTS (0x08B9) 2233
; Indent IDM_INDENT (0x088A) 2186 Отступ от левого края
; InlineDirLTR IDM_INLINEDIRLTR (0x0932) 2354
; InlineDirRTL IDM_INLINEDIRRTL (0x0933) 2355
; InsertButton IDM_BUTTON (0x0877) 2167 кнопка
; InsertFieldset IDM_INSFIELDSET (0x0847) 2119 предназначен для группирования элементов формы
; InsertHorizontalRule IDM_HORIZONTALLINE (0x0866) 2150 горизонтальная линия
; InsertIFrame IDM_IFRAME (0x086E) 2158 создает плавающий фрейм, который находится внутри обычного документа
; InsertImage IDM_IMAGE (0x0878) 2168 вставить изображения
; InsertInputButton IDM_INSINPUTBUTTON (0x0843) 2115 радио кнопка
; 2116 кнопко сброс
; InsertInputCheckbox IDM_CHECKBOX (0x0873) 2163 флажок
; 2164 кнопка радио
; InsertInputFileUpload IDM_INSINPUTUPLOAD (0x0846) 2118 кнопка загрузить файл
; InsertInputHidden IDM_INSINPUTHIDDEN (0x0908) 2312 создать скрытое поле
; InsertInputImage IDM_INSINPUTIMAGE (0x0842) 2114 кнопка с изображением
; InsertInputPassword IDM_INSINPUTPASSWORD (0x0909)
; InsertInputRadio IDM_RADIOBUTTON (0x0874)
; InsertInputReset IDM_INSINPUTRESET (0x0844)
; InsertInputSubmit IDM_INSINPUTSUBMIT (0x0845) 2117 кнопка
; InsertInputText IDM_TEXTBOX (0x0871) 2161 текстовое поле
; InsertMarquee IDM_MARQUEE (0x0886) 2182 создать бегущею строку
; InsertOrderedList IDM_ORDERLIST (0x0888) 2184 нумерованный список
; InsertParagraph IDM_PARAGRAPH (0x0884) 2180 <P></P>
; InsertSelectDropdown IDM_DROPDOWNBOX (0x0875) 2165 раскрывающейся список
; InsertSelectListbox IDM_LISTBOX (0x0876) 2166 LISTBOX
; InsertTextArea IDM_TEXTAREA (0x0872) 2162 текстовое поле с переносом строки
; InsertUnorderedList IDM_UNORDERLIST (0x0889) 2185 не нумерованный список
; Italic IDM_ITALIC (0x0038) 56 шрифт Italic
; JustifyCenter IDM_JUSTIFYCENTER (0x0039) 57 текст по центру
; JustifyFull IDM_JUSTIFYFULL (0x0032) 50
; JustifyLeft IDM_JUSTIFYLEFT (0x003B) 59 выровнять по левому краю
; JustifyNone IDM_JUSTIFYNONE (0x005E) 94 не выравнивать
; JustifyRight IDM_JUSTIFYRIGHT (0x003C) 60 веровнять по правому краю
; KeepSelection IDM_KEEPSELECTION (0x096A) 2410
; LiveResize IDM_LIVERESIZE (0x095E) 2398
; MultipleSelection IDM_MULTIPLESELECTION (0x0959) 2393
; Open IDM_OPEN (0x07D0) 2000
; Outdent IDM_OUTDENT (0x088B) 2187
; OverWrite IDM_OVERWRITE (0x090A) 2314
; Paste IDM_PASTE (0x001A) 26 вставить из буфера обмена
; PlayImage IDM_DYNSRCPLAY (0x08DF) 2271
; Print IDM_EXECPRINT (0x005D) 93 принт
; Redo IDM_REDO (0x001D) 29 на шаг вперёд
; Refresh IDM_REFRESH (0x08FC) 2300 обновить браузер
; RemoveFormat IDM_REMOVEFORMAT (0x08B6) 2230
; RemoveParaFormat IDM_REMOVEPARAFORMAT (0x08CD) 2253
; RespectVisibilityInDesign IDM_RESPECTVISIBILITY_INDESIGN (0x0965) 2405
; SaveAs IDM_SAVEAS (0x0047) 71 сохранить
; SelectAll IDM_SELECTALL (0x001F) 31 выделить всё
; SizeToControl IDM_SIZETOCONTROL (0x0023) 35
; SizeToControlHeight IDM_SIZETOCONTROLHEIGHT (0x0024) 36
; SizeToControlWidth IDM_SIZETOCONTROLWIDTH (0x0025) 37
; Stop IDM_STOP (0x085A) 2138
; StopImage IDM_DYNSRCSTOP (0x08E0) 2272
; StrikeThrough IDM_STRIKETHROUGH (0x005B) 91 текст зочёркнут
; Subscript IDM_SUBSCRIPT (0x08C7) 2247 текст в нижнем регистре
; Superscript IDM_SUPERSCRIPT (0x08C8) 2248 текст в верхнем регистре
; TristateBold IDM_TRISTATEBOLD (0x005F) 95 жирный
; TristateItalic IDM_TRISTATEITALIC (0x0060) 96 ITALIC
; TristateUnderline IDM_TRISTATEUNDERLINE (0x0061) 97 текст подчёркнутый
; UIOutdent IDM_UI_OUTDENT (0x0967) 2407
; UnBookmark IDM_UNBOOKMARK (0x0850) 2128
; Underline IDM_UNDERLINE (0x003F) 63 текст подчёркнутый
; Undo IDM_UNDO (0x002B) 43 на шаг назад
; UnloadDocument IDM_UNLOADDOCUMENT (0x096B) 2411
; Unlink IDM_UNLINK (0x084D) 2125
; Unselect IDM_CLEARSELECTION (0x07D7) 2007 снять выделение
; 25 вставка обьектов
; 27 печать
; 90 выбор шрифта и размер
; 92 удалить выделенное
; 2003 предватительный просмотр печати
; 2004 параметры страницы
; 2135 вызов сетевого обозревателя
; 2139 вызов блакнота с кодом
; 2143 размер шрифта в системе
; 2144 размер шрифта в системе
; 2145 размер шрифта в системе
; 2151 добавить строчку
; 2152 с новой строки тег <br clear=left>
; 2153 с новой строки тег <br clear=right>
; 2154 с новой строки тег <br clear=all>
; 2155 добавить пробел
; 2170 <DIV> </DIV>
; 2180 <P></P>
; 2221 сообщение о версии браузера
; 2261 добавить стр в избранное
; 2266 добавить ярлык на раб стол
; 2280 контекстное меню
; 2312 поле
; 2313 поле
; 2351 печатать с право на лево
; 2353 печатать с право на лево
; 2357 <SPAN class=""></SPAN>
; 2371 вызов блакнота с кодом
;
;
</plaintext>
</div><br><br><br>
<IMG height=20 alt="Уроки PureBasic" src="img/lin.jpg" width=700><BR><BR>
Скачать <a href="fail/Visual_Editor.rar">архив</a><BR><BR><BR>
<IMG height=20 alt="Уроки PureBasic" src="img/lin.jpg" width=700><BR><BR><br>
</DIV>
</DIV>
<!-- copyright (t4) --><div align="center">Используются технологии <a href="http://www.ucoz.ru/" title="Создать сайт бесплатно"><b>uCoz</b></a><br /></div><!-- /copyright -->
</body>
</html>
]]></plaintext></div></div></div> 